// greaternpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Greaternpc.txt is a script that relies upon the setting of memory cells, something that
// can only be done in towns.  So it is quite useless outside of towns.
// It is meant to enable the use of certain Exile features in a BoA scenario

// Memory Cells:
//   Cell 0 - How creature moves.
//     		0 - If 0, wander randomly. 
//     		1 - Stands still until a target appears.
//     		2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - A state called if creature dies.
//   Cell 5 - A state that can be called every combat round.
//   Cell 6 - Percentage chance of summoning a monster.*
//   Cell 7 - Type of monster that can be summoned.
//   Cell 8 - Not currently used.
//   Cell 9 - Not currently used.


begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	inc_flag(100,11,5);
	print_named_str(ME,"dies!");
	if ((get_memory_cell(1) > 0) && (get_memory_cell(2) > 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
	if (get_memory_cell(4) >= 10)	
			run_town_script(get_memory_cell(4));
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}

		if (get_memory_cell(5) >= 10)	
			run_town_script(get_memory_cell(5));	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
	if (get_ran(1,1,100) <= get_memory_cell(6)) {
	print_named_str(ME,"summons a monster!");
	run_animation_sound(160);
	place_monster(my_loc_x(),my_loc_y(),get_memory_cell(7),0);
}
break;
	
beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
		}
	begin_talk_mode(get_memory_cell(3));
break;
